#
#  Copyright (c) 2024, The OpenThread Authors.
#  All rights reserved.
#
#  Redistribution and use in source and binary forms, with or without
#  modification, are permitted provided that the following conditions are met:
#  1. Redistributions of source code must retain the above copyright
#     notice, this list of conditions and the following disclaimer.
#  2. Redistributions in binary form must reproduce the above copyright
#     notice, this list of conditions and the following disclaimer in the
#     documentation and/or other materials provided with the distribution.
#  3. Neither the name of the copyright holder nor the
#     names of its contributors may be used to endorse or promote products
#     derived from this software without specific prior written permission.
#
#  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
#  AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
#  IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
#  ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
#  LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
#  CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
#  SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
#  INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
#  CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
#  ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
#  POSSIBILITY OF SUCH DAMAGE.
#

cmake_minimum_required(VERSION 3.14)
project(openthread-gtest)

find_package(GTest CONFIG REQUIRED COMPONENTS GTest GMock Main)

# GoogleTest requires at least C++14
set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

include(GoogleTest)

add_library(ot-fake-platform
    fake_platform.cpp
)
target_link_libraries(ot-fake-platform
    ot-config
)

add_library(ot-fake-ftd INTERFACE)
target_compile_definitions(ot-fake-ftd INTERFACE
    OPENTHREAD_FTD=1
    OPENTHREAD_MTD=0
    OPENTHREAD_RADIO=0
)
target_link_libraries(ot-fake-ftd INTERFACE
    openthread-ftd
    ot-fake-platform
)

add_executable(ot-ftd-gtest
    dataset_test.cpp
    udp_test.cpp
)
target_link_libraries(ot-ftd-gtest
    ot-fake-ftd
    GTest::gtest
    GTest::gmock
    GTest::gtest_main
)
gtest_discover_tests(ot-ftd-gtest)

add_executable(ot-posix-gtest
    multicast_forwarding_test.cpp
    ${openthread_SOURCE_DIR}/src/posix/platform/multicast_forwarding.cpp
)

target_include_directories(ot-posix-gtest PRIVATE
    ${openthread_SOURCE_DIR}/src
    ${openthread_SOURCE_DIR}/src/core
    ${openthread_SOURCE_DIR}/src/posix/platform
)

target_link_libraries(ot-posix-gtest
    ot-fake-ftd
    GTest::gtest
    GTest::gtest_main
)

gtest_discover_tests(ot-posix-gtest)

# The BPF tap exists only where BPF does. Its source is compiled under the Backbone Router multicast routing
# configuration, which the test turns on for itself so that it runs whether or not the build enables the Backbone
# Router; only an explicit OT_BACKBONE_ROUTER=OFF, where ot-config already defines the guard as 0, leaves it out.
if(NOT CMAKE_SYSTEM_NAME STREQUAL "Linux" AND (OT_BACKBONE_ROUTER OR OT_BACKBONE_ROUTER STREQUAL ""))
    add_executable(ot-posix-bpf-gtest
        bpf_tap_test.cpp
        ${openthread_SOURCE_DIR}/src/posix/platform/bpf_tap.cpp
    )

    target_compile_definitions(ot-posix-bpf-gtest PRIVATE
        OPENTHREAD_CONFIG_BACKBONE_ROUTER_ENABLE=1
        OPENTHREAD_CONFIG_BACKBONE_ROUTER_MULTICAST_ROUTING_ENABLE=1
        OPENTHREAD_POSIX_CONFIG_BACKBONE_ROUTER_MULTICAST_ROUTING_ENABLE=1
    )

    target_include_directories(ot-posix-bpf-gtest PRIVATE
        ${openthread_SOURCE_DIR}/src
        ${openthread_SOURCE_DIR}/src/core
        ${openthread_SOURCE_DIR}/src/posix/platform
    )

    target_link_libraries(ot-posix-bpf-gtest
        ot-fake-ftd
        GTest::gtest
        GTest::gtest_main
    )

    gtest_discover_tests(ot-posix-bpf-gtest)
endif()

add_library(ot-fake-rcp
    fake_coprocessor_platform.cpp
)
target_link_libraries(ot-fake-rcp
    openthread-hdlc
    openthread-rcp
    openthread-radio-spinel
    openthread-radio
    ot-fake-platform
)

add_executable(ot-radio-spinel-rcp-gtest
    radio_spinel_rcp_test.cpp
)
target_link_libraries(ot-radio-spinel-rcp-gtest
    ot-fake-rcp
    GTest::gtest
    GTest::gmock
    GTest::gtest_main
)

gtest_discover_tests(ot-radio-spinel-rcp-gtest)
